Y 分鐘速成 Haskell 詳情 - haskell,函數式編程,語法,入門小X學技術博客

源代碼下載： learn-haskell-zh.hs

Haskell 是一門實用的函數式編程語言，因其 Monads 與類型系統而聞名。而我使用它則是因為它異常優雅。用 Haskell 編程令我感到非常快樂。

-- 單行註釋以兩個減號開頭
{- 多行註釋像這樣
    被一個閉合的塊包圍
-}

----------------------------------------------------
-- 1. 簡單的數據類型和操作符
----------------------------------------------------

-- 數字
3 -- 3
-- 數學計算
1 + 1 -- 2
8 - 1 -- 7
10 * 2 -- 20
35 / 5 -- 7.0

-- 默認除法不是整除
35 / 4 -- 8.75

-- 整除
35 `div` 4 -- 8

-- 布爾值
True
False

-- 布爾操作
not True -- False
not False -- True
1 == 1 -- True
1 /= 1 -- False
1 < 10 -- True

-- 在上面的例子中，`not` 是一個接受一個參數的函數。
-- Haskell 不需要括號來調用函數，所有的參數都只是在函數名之後列出來
-- 因此，通常的函數調用模式是：
--   func arg1 arg2 arg3...
-- 你可以查看函數部分了解如何自行編寫。

-- 字符串和字符
"This is a string." -- 字符串
'a' -- 字符
'對於字符串你不能使用單引號。' -- 錯誤！

-- 連接字符串
"Hello " ++ "world!" -- "Hello world!"

-- 一個字符串是一系列字符
['H', 'e', 'l', 'l', 'o'] -- "Hello"
"This is a string" !! 0 -- 'T'


----------------------------------------------------
-- 2. 列表和元組
----------------------------------------------------

-- 一個列表中的每一個元素都必須是相同的類型。
-- 下面兩個列表等價
[1, 2, 3, 4, 5]
[1..5]

-- 區間也可以這樣
['A'..'F'] -- "ABCDEF"

-- 你可以在區間中指定步進
[0,2..10] -- [0, 2, 4, 6, 8, 10]
[5..1] -- 這樣不行，因為 Haskell 默認遞增
[5,4..1] -- [5, 4, 3, 2, 1]

-- 列表下標
[0..] !! 5 -- 5

-- 在 Haskell 你可以使用無限列表
[1..] -- 一個含有所有自然數的列表

-- 無限列表的原理是，Haskell 有“惰性求值”。
-- 這意味着 Haskell 只在需要時才會計算。
-- 所以當你獲取列表的第 1000 項元素時，Haskell 會返回給你：
[1..] !! 999 -- 1000
-- Haskell 計算了列表中第 1 至 1000 項元素，但這個無限列表中剩下的元素還不存在。
-- Haskell 只有在需要時才會計算它們。

-- 連接兩個列表
[1..5] ++ [6..10]

-- 往列表頭增加元素
0:[1..5] -- [0, 1, 2, 3, 4, 5]

-- 其它列表操作
head [1..5] -- 1
tail [1..5] -- [2, 3, 4, 5]
init [1..5] -- [1, 2, 3, 4]
last [1..5] -- 5

-- 列表推導 (list comprehension)
[x*2 | x <- [1..5]] -- [2, 4, 6, 8, 10]

-- 附帶條件
[x*2 | x <-[1..5], x*2 > 4] -- [6, 8, 10]

-- 元組中的每一個元素可以是不同類型，但是一個元組的長度是固定的
-- 一個元組
("haskell", 1)

-- 獲取元組中的元素（例如，一個含有 2 個元素的元祖）
fst ("haskell", 1) -- "haskell"
snd ("haskell", 1) -- 1

----------------------------------------------------
-- 3. 函數
----------------------------------------------------

-- 一個接受兩個變量的簡單函數
add a b = a + b

-- 注意，如果你使用 ghci (Haskell 解釋器)，你需要使用 `let`，也就是
-- let add a b = a + b

-- 調用函數
add 1 2 -- 3

-- 你也可以使用反引號中置函數名：
1 `add` 2 -- 3

-- 你也可以定義不帶字母的函數名，這樣你可以定義自己的操作符。
-- 這裏有一個做整除的操作符
(//) a b = a `div` b
35 // 4 -- 8

-- Guard：一個在函數中做條件判斷的簡單方法
fib x
  | x < 2 = x
  | otherwise = fib (x - 1) + fib (x - 2)

-- 模式匹配與 Guard 類似。
-- 這裏給出了三個不同的 fib 定義。
-- Haskell 會自動調用第一個符合參數模式的聲明
fib 1 = 1
fib 2 = 2
fib x = fib (x - 1) + fib (x - 2)

-- 元組的模式匹配
foo (x, y) = (x + 1, y + 2)

-- 列表的模式匹配
-- 這裏 `x` 是列表中第一個元素，`xs` 是列表剩餘的部分。
-- 我們可以實現自己的 map 函數：
myMap func [] = []
myMap func (x:xs) = func x:(myMap func xs)

-- 匿名函數帶有一個反斜槓，後面跟着所有的參數
myMap (\x -> x + 2) [1..5] -- [3, 4, 5, 6, 7]

-- 在 fold（在一些語言稱 為`inject`）中使用匿名函數
-- foldl1 意味着左摺疊 (fold left), 並且使用列表中第一個值作為累加器的初始值。
foldl1 (\acc x -> acc + x) [1..5] -- 15

----------------------------------------------------
-- 4. 其它函數
----------------------------------------------------

-- 部分調用
-- 如果你調用函數時沒有給出所有參數，它就被“部分調用”。
-- 它將返回一個接受餘下參數的函數。
add a b = a + b
foo = add 10 -- foo 現在是一個接受一個數並對其加 10 的函數
foo 5 -- 15

-- 另一種等價寫法
foo = (+10)
foo 5 -- 15

-- 函列表合
-- (.) 函數把其它函數鏈接到一起。
-- 例如，這裏 foo 是一個接受一個值的函數。
-- 它對接受的值加 10，並對結果乘以 5，之後返回最後的值。
foo = (*5) . (+10)

-- (5 + 10) * 5 = 75
foo 5 -- 75

-- 修正優先級
-- Haskell 有另外一個函數 `$` 可以改變優先級。
-- `$` 使得 Haskell 先計算其右邊的部分，然後調用左邊的部分。
-- 你可以使用 `$` 來移除多餘的括號。

-- 修改前
(even (fib 7)) -- False

-- 修改後
even . fib $ 7 -- False

-- 等價地
even $ fib 7 -- False

----------------------------------------------------
-- 5. 類型聲明
----------------------------------------------------

-- Haskell 有一個非常強大的類型系統，一切都有一個類型聲明。

-- 一些基本的類型：
5 :: Integer
"hello" :: String
True :: Bool

-- 函數也有類型
-- `not` 接受一個布爾型返回一個布爾型
-- not :: Bool -> Bool

-- 這是接受兩個參數的函數
-- add :: Integer -> Integer -> Integer

-- 當你定義一個值，聲明其類型是一個好做法
double :: Integer -> Integer
double x = x * 2

----------------------------------------------------
-- 6. 控制流和 If 語句
----------------------------------------------------

-- if 語句：
haskell = if 1 == 1 then "awesome" else "awful" -- haskell = "awesome"

-- if 語句也可以有多行，注意縮進：
haskell = if 1 == 1
            then "awesome"
            else "awful"

-- case 語句
-- 解析命令行參數：
case args of
  "help" -> printHelp
  "start" -> startProgram
  _ -> putStrLn "bad args"

-- Haskell 沒有循環，它使用遞歸
-- map 對一個列表中的每一個元素調用一個函數
map (*2) [1..5] -- [2, 4, 6, 8, 10]

-- 你可以使用 map 來編寫 for 函數
for array func = map func array

-- 調用
for [0..5] $ \i -> show i

-- 我們也可以像這樣寫
for [0..5] show

-- 你可以使用 foldl 或者 foldr 來分解列表
-- foldl <fn> <initial value> <list>
foldl (\x y -> 2*x + y) 4 [1,2,3] -- 43

-- 等價於
(2 * (2 * (2 * 4 + 1) + 2) + 3)

-- foldl 從左開始，foldr 從右
foldr (\x y -> 2*x + y) 4 [1,2,3] -- 16

-- 現在它等價於
(2 * 3 + (2 * 2 + (2 * 1 + 4)))

----------------------------------------------------
-- 7. 數據類型
----------------------------------------------------

-- 在 Haskell 中聲明你自己的數據類型：
data Color = Red | Blue | Green

-- 現在你可以在函數中使用它：
say :: Color -> String
say Red = "You are Red!"
say Blue = "You are Blue!"
say Green =  "You are Green!"

-- 你的數據類型也可以有參數：
data Maybe a = Nothing | Just a

-- 這些都是 Maybe 類型：
Just "hello"    -- `Maybe String` 類型
Just 1          -- `Maybe Int` 類型
Nothing         -- 對任意 `a` 為 `Maybe a` 類型

----------------------------------------------------
-- 8. Haskell IO
----------------------------------------------------

-- 雖然不解釋 Monads 就無法完全解釋 IO，但大致瞭解並不難。

-- 當執行一個 Haskell 程序時，函數 `main` 就被調用。
-- 它必須返回一個類型 `IO ()` 的值。例如：
main :: IO ()
main = putStrLn $ "Hello, sky! " ++ (say Blue) 
-- putStrLn 的類型是 String -> IO ()

-- 如果你的程序輸入 String 返回 String，那樣編寫 IO 是最簡單的。
-- 函數
--    interact :: (String -> String) -> IO ()
-- 輸入一些文本，對其調用一個函數，並打印輸出。

countLines :: String -> String
countLines = show . length . lines

main' = interact countLines

-- 你可以認為一個 `IO ()` 類型的值是表示計算機做的一系列操作，類似命令式語言。
-- 我們可以使用 `do` 聲明來把動作連接到一起。
-- 舉個列子
sayHello :: IO ()
sayHello = do 
   putStrLn "What is your name?"
   name <- getLine -- 這裏接受一行輸入並綁定至 "name"
   putStrLn $ "Hello, " ++ name
   
-- 練習：編寫只讀取一行輸入的 `interact`
   
-- 然而，`sayHello` 中的代碼將不會被執行。唯一被執行的動作是 `main` 的值。
-- 為了運行 `sayHello`，註釋上面 `main` 的定義，替換為：
--   main = sayHello

-- 讓我們來更進一步理解剛才所使用的函數 `getLine` 是怎樣工作的。它的類型是：
--    getLine :: IO String
-- 你可以認為一個 `IO a` 類型的值代表了一個運行時會生成一個 `a` 類型值的程序。
-- （可能伴隨其它行為）
-- 我們可以通過 `<-` 保存和重用這個值。
-- 我們也可以實現自己的 `IO String` 類型函數：
action :: IO String
action = do
   putStrLn "This is a line. Duh"
   input1 <- getLine 
   input2 <- getLine
   -- `do` 語句的類型是它的最後一行
   -- `return` 不是關鍵字，只是一個普通函數
   return (input1 ++ "\n" ++ input2) -- return :: String -> IO String

-- 我們可以像調用 `getLine` 一樣調用它
main'' = do
    putStrLn "I will echo two lines!"
    result <- action 
    putStrLn result
    putStrLn "This was all, folks!"

-- `IO` 類型是一個 "Monad" 的例子。
-- Haskell 通過使用 Monad 使得其本身為純函數式語言。
-- 任何與外界交互的函數（即 IO）都在它的類型聲明中標記為 `IO`。
-- 這告訴我們什麼樣的函數是“純潔的”(不與外界交互，不修改狀態) ，
-- 什麼樣的函數不是 “純潔的”。
-- 這個功能非常強大，因為純函數併發非常容易，由此在 Haskell 中做併發非常容易。

----------------------------------------------------
-- 9. Haskell REPL
----------------------------------------------------

-- 鍵入 `ghci` 開始 REPL。
-- 現在你可以鍵入 Haskell 代碼。
-- 任何新值都需要通過 `let` 來創建
let foo = 5

-- 你可以通過命令 `:t` 查看任何值的類型
>:t foo
foo :: Integer

-- 你也可以運行任何 `IO ()`類型的動作
> sayHello
What is your name?
Friend!
Hello, Friend!

Haskell 還有許多內容，包括類型類 (typeclasses) 與 Monads。這些都是令 Haskell 編程非常有趣的好東西。我們最後給出 Haskell 的一個例子，一個快速排序的實現：

qsort [] = []
qsort (p:xs) = qsort lesser ++ [p] ++ qsort greater
    where lesser  = filter (< p) xs
          greater = filter (>= p) xs

安裝 Haskell 很簡單，你可以從這裏獲得。

你可以從優秀的 Learn you a Haskell 或者 Real World Haskell 找到更平緩的入門介紹。

有建議？或者發現什麼錯誤？在 Github 上開一個 issue，或者發起 pull request ！

小X學技術博客

小X學技術博客

博客 / 詳情

Y 分鐘速成 Haskell

發佈評論

Product

Company

Support

Company

博客 / 詳情

Y 分鐘速成 Haskell

發佈 評論

發佈評論